A Deep Dive Into Filing Mail Messages Using AppleScript

There are a number of techniques I am looking into to file messages into macOS Mail mailboxes using AppleScript for the macOS Sonoma version of MsgFiler, but each possible solution has its own set of drawbacks and limitations. Let’s dive into each one, but first some background on how MsgFiler with the Engine used to work in macOS Ventura and earlier:

MsgFiler + Engine

In macOS Ventura and before, the Engine Mail Plug-in has direct access to Mail’s internal functions. As a result, all MsgFiler had to do was call this method:

[messageViewer transferSelectedMessagesToMailbox:mailbox moveMessages:YES];

So simple and easy. Sadly, macOS Sonoma removed the ability to install and run Mail Plug-ins, so here we are.

Via the Antiquated Mail Dictionary

The AppleScript dictionary for the Mail application reveals a number of ways to file a message. Consider the following example:

• Mailbox account is Gmail
• Destination mailbox is called “Test”

Here is a sample AppleScript that shows the different ways to file the currently selected message or messages:

set theMessages to get selection 
set theMailbox to mailbox "Test" in account "gmail.com"

repeat with theMessage in theMessages
	set mailbox of theMessage to theMailbox

-- Or
	move theMessage to theMailbox
end repeat

Normally, I would use the set command on the mailbox property of a message. The problem happens when the account of the message being filed is Gmail. Gmail’s IMAP implementation is non-standard in how it handles labels and mailboxes. When you apply a label to a message, you’re not moving it to a separate folder; you’re tagging it with that label.

In macOS Mail, manually moving a message from the inbox of a Gmail account removes the Inbox label and applies the label of the destination mailbox. This also happens when you use the Move to menu under the Message menu.

When moving messages using AppleScript, however, the Inbox label is not removed from the moved message. As a result, the message looks like it has been duplicated. It appears both in the Inbox and in the destination mailbox. In order to remove the message from the Inbox, one needs to archive it. You can accomplish this by using the AppleScript Accessibility API as follows:

tell application "Mail" to activate
tell application "System Events"
	tell menu bar 1 of application process "Mail"

		tell menu bar item 7
 -- Message
			tell menu 1
				tell menu 19 -- Archive
					if enabled then
						click
					end if
				end tell
			end tell
		end tell
	end tell
end tell

Now, if the account of the message is not Gmail, calling the set mailbox command will automatically remove the message from the Message Viewer. What it won’t do, however, is select the next message in the Message Viewer. The selection disappears, forcing you to use the mouse or trackpad to select the next message to file. One can get around this by sending the down arrow key code to the Mac:

tell application "System Events" to key code 125

Putting it all together, one can create a script that takes a mailbox path and files it, optionally selecting the next message or archiving the message is it’s from Gmail:

tell application "Mail"
	set theMessages to get selection 
	set theMailbox to mailbox "Test" in account "gmail.com"
	set toArchive to false

	repeat with theMessage in theMessages
		set mailbox of theMessage to theMailbox
	
		if account of theMessage contains "gmail" then
			set toArchive to true
		end if

		if toArchive is false then
			tell application "System Events" to key code 125
		end if
	end repeat

	if toArchive then
		tell application "System Events"
			tell menu item 19 of menu 1 of menu bar item 7 of menu bar 1 of application process "Mail"
				if enabled then
					click
				end if
			end tell
		end tell
	end if
end tell

Now there’s a problem with this approach and that’s if multiple messages are selected that belong to different mail accounts. It’s possible that the selection will change by applying the arrow down key code to Mail. This could cause the wrong message to be archived and keep duplicate emails in the Inbox.

This is roughly the approach that Ike Nassi’s Keyboard Maestro macros uses to file messages.

Using the Move to Menu

This has led to be to investigating whether it’s possible to use the Message > Move to menu item to file messages. This approach has the benefit of using Apple’s built-in methods for filing messages instead of its aging and out-of-date AppleScript method. When you use the Move to menu, it’s just like dragging and dropping the message into a mailbox.

In its simplest form, we take the path to the mailbox and locate the correct mailbox in the menu. When the mailbox hierarchy is completely collapsed, items in the Move to menu match what you would expect:

• Message
  • Move to
    • Gmail.com
      • Archive
      • Sent
      • Trash
      • Junk
      • Test

It’s relatively simple to locate the mailbox by traversing the menu item hierarchy:

tell application "Mail" to activate

	tell application "System Events"

		tell menu bar 1 of application process "Mail"
	
		tell menu item "Test" of menu 1 of menu item "Gmail.com" of menu 1 of menu item 21 of menu 1 of menu bar item 7

				click

		end tell

	end tell

end tell

Targeting a Folder with Children

What if you wanted to file messages to a folder that contained mailboxes:

• Gmail.com
  •  Finances
    • Bills
    • Orders

Tell AppleScript to click on the Finances folder doesn’t do what you would expect. It displays the Finances menu, but selects the first child, Bills. The solution is to use System Events to simulate the Left Arrow key, followed by pressing Return:

tell application "System Events"
	click at {x, y}
	delay 0.1
	key code 123
	delay 0.1
	keystroke return
											end tell

Where x and y are the coordinates of the destination menu (i.e. Finances). Fortunately, the position of the menu is provided to AppleScript.

Expanding Hierarchy Problems

Now, what happens if the mailbox hierarchy was expanded? The Move to menu changes to reflect the expanded hierarchy. The way Apple does this, however, leaves much ambiguity for AppleScript as to the correct position of a mailbox.

• Message
  • Move to
    • Gmail.com
    •  Test

See the difference? Test is on the same level as its account Gmail.com. AppleScript, given the Test menu item, can’t easily determine if it’s part of Gmail.com or a different account. This becomes extremely complicated if you have multiple mailboxes with the same name. Consider this:

• Message
  • Move to
    • iCloud
    •  Test
    • Gmail.com
    •  Test

You can no longer use the script above because iCloud and Gmail.com are expanded so there is nothing to be found in their list of menu items (it returns 0). If those two accounts were collapsed, we could find the correct Test mailbox. As it stands, both Test mailboxes could easily be the one chosen, which is not good. And, if you have more mailboxes with the same name, it gets even more complicated!

• Message
  • Move to
    • Gmail.com
    •  Misc
    •   Test
    •   To Followup
    •  Project A
    •   People
    •   Test
    • Test

Will the right mailbox please stand up?

Say you keep track of things to follow-up in multiple mailboxes. When the mailbox hierarchy is expanded, the Move to menu is flattened and it’s very difficult, downright impossible in a timely manner, to determine which Test belongs to which folder and which account.

You might say, “Okay, I’ll just collapse my mailbox hierarchy before I file any messages.” The problem with this is what happens if you’re looking at a deeply nested mailbox and you want to another mailbox that is hard to disambiguate? If you collapse the mailbox hierarchy, Mail will remove focus from your message and show a blank screen.

Mailbox hierarchy has been collapsed, but focus on the message has disappeared.

Enforce Unique Mailbox Names

One way around this is to enforce unique mailbox names, or at least allow filing when MsgFiler can locate one and only one mailbox. Question for current and past MsgFiler owners is how often do you have mailboxes with the same name across accounts and in different mailboxes? Leave your response in a comment below.

Question for current and past MsgFiler owners is how often do you have mailboxes with the same name across accounts and in different mailboxes?

Special Gmail Folders

The Move to menu method has another weakness. The mailbox path for Gmail’s special mailboxes like Important, Archive, Trash, Junk, etc. are prefixed with the string [Gmail], which is not displayed in the Move to > Message menu. So, there’s no way to target these mailboxes using the Move to AppleScript method.

App Sandbox and System Events

There’s an even bigger problem with updating MsgFiler and that is its use of System Events to send commands and key codes to the Mail application. While MsgFiler has a temporary entitlement to control Apple Mail via AppleScript, it does not have an entitlement for sending AppleScript to System Events. Nor is Apple providing such an entitlement, since that can be a vector for sending arbitrary key strokes and commands to any application.

As a result, any solution using these two methods will likely cause MsgFiler to be rejected by the Mac App Store. I will have to pull MsgFiler from the App Store and find an alternative distribution mechanism with the app (i.e. Gumroad?). This means adding back in license code validation and other things I really don’t want to have to do.

More Challenges Ahead

These are some of the challenges that I’m working through to get MsgFiler to work on macOS Sonoma. The degree of difficult is why I continue to recommend the workarounds posted before or just to manually file in the Mail app.

It’s looking unlikely that I’ll be able to get 100% feature parity with MsgFiler 3 + Engine, but maybe I don’t need to. How many people have mailboxes with the same name? If the number is small, I can accelerate the Move to menu approach. If people don’t mind some slowdown, maybe the pure AppleScript approach will work better.

Of course, all of this can be solved if Apple just were to implement MsgFiler’s functionality into the native Mail app directly. Sherlock MsgFiler, Apple! Please continue to leave feedback to the Apple Mail team by emailing: mail-app-extensions@apple.com

Which approach do you like and why? Let me know your thoughts in the comments below.